*Solved *Rules not working

[SoN]

Hi, i don't know why this code isn't working:

Code: Select all

On System#Boot do
TaskValueSet,5,1,1 //Dummy-Task5 Para#SP
TaskValueSet,5,2,1 //Dummy-Task5 Para#HYST
endOn

On WW-VL#Temp do // WW-VL#Temp = DS18B20 Nr1  WW-RL#Temp = DS18B20 Nr2
   if [Para#HYST] = 1
   TaskValueSet,5,1,([WW-VL#Temp]-[WW-RL#Temp]) //Temp-Diff in Para#SP
      if [Para#SP] > 5
        gpio,5,1
        TaskValueSet,5,2,0
        timerSet,1,180
      endif
   endif
endOn

On Rules#Timer=1 do
    gpio,5,0
    timerSet,2,3600 //Pause 1h
endOn

On Rules#Timer=2 do
    TaskValueSet,5,2,1 
endOn

If enabled, the esp webserver is no longer accessible. a permanent ping results in irregular timeouts. for brief moments the esp answers

Please can someone explain why?
Thank You

[grovkillen]

This section here is not allowed (nesting if statements are not possible in the esp easy rule engine... please study the wiki on how to overcome this "problem")

Code: Select all

   if [Para#HYST] = 1
   TaskValueSet,5,1,([WW-VL#Temp]-[WW-RL#Temp]) //Temp-Diff in Para#SP
      if [Para#SP] > 5
        gpio,5,1
        TaskValueSet,5,2,0
        timerSet,1,180
      endif
   endif

[SoN]

Thank you !!
is this ok?
for 1. try ... isn't working

Code: Select all

On System#Boot do
TaskValueSet,5,1,1 //Dummy-Task5 Para#SP
TaskValueSet,5,2,1 //Dummy-Task5 Para#HYST
endOn

On WW-VL#Temp do // WW-VL#Temp = DS18B20 Nr1  WW-RL#Temp = DS18B20 Nr2
if [Para#HYST] = 1
TaskValueSet,5,1,([WW-VL#Temp]-[WW-RL#Temp]) //Temp-Diff in Para#SP
event <pump-on>     
endif
endOn


on <pump-on> do
if [Para#SP] > 5
gpio,5,1
TaskValueSet,5,2,0
timerSet,1,180
endif
endon

On Rules#Timer=1 do
gpio,5,0
timerSet,2,3600 //Pause 1h
endOn

On Rules#Timer=2 do
TaskValueSet,5,2,1 
endOn

[vader]

Try this...

on Para#HYST = 1 do
TaskValueSet,5,1,[WW-VL#Temp]-[WW-RL#Temp] //Temp-Diff in Para#SP
if [Para#SP] > 5
gpio,5,1
TaskValueSet,5,2,0
timerSet,1,180
endif
endon

[SoN]

as soon as I activate the rules the esp is not reliable anymore.
many timeouts.
it is a matter of luck if the web interface responds.
Load on Main-page is 75%, without rules 0%
is it possible that there is an endless loop?

without this line everything is ok:
TaskValueSet,5,1,[WW-VL#Temp]-[WW-RL#Temp]

do i need a delay for reading the ds18b20 sensors?

[vader]

You have
on <pump-on> do

Correct it to: on pump-on do

Or better change all to "pumpon" or "pump_on". Maybe the parser has a problem with the "-" in the name!

Normally sensors have a delay of 60 sec. Post a screenshot of yours....

[SoN]

This works :

Code: Select all

On System#Boot do
TaskValueSet,5,1,1 //Dummy-Task5 Para#SP
TaskValueSet,5,2,1 //Dummy-Task5 Para#HYST
endon

On WW-VL#Temp do // WW-VL#Temp = DS18B20 Nr1  WW-RL#Temp = DS18B20 Nr2
if [Para#HYST] = 1
TaskValueSet,5,1,([WW-VL#Temp]-[WW-RL#Temp]) //Temp-Diff in Para#SP
event pumpon
endif
endon

on pumpon do
if [Para#SP] > 5
gpio,5,1
TaskValueSet,5,2,0
timerSet,1,180
endif
endon

On Rules#Timer=1 do
gpio,5,0
timerSet,2,3600 //Pause 1h
endon

On Rules#Timer=2 do
TaskValueSet,5,2,1
endon

Thank you for help

[vader]

Supi. U r welcome.

You can change this
TaskValueSet,5,1,([WW-VL#Temp]-[WW-RL#Temp])
into this
TaskValueSet,5,1,[WW-VL#Temp]-[WW-RL#Temp]

because it's just a simple subtraction, so we don't need the brackets