Why is this rule not working?

[micropet]

I want the Neopixels to be bright during the day and darker in the evening.
They should show me the CO2 value.

The following rule does not work:

Code: Select all

on MH-Z19#PPM do
	if [MH-Z19#PPM]<=700
		if %systime% > 08:00:00 and %systime% < 20:00:00 
			NeoPixelAll,0,80,0,0  // gruen tagsueber
		else
			NeoPixelAll,0,8,0,0   // gruen abends
		endif
	endif

	if [MH-Z19#PPM]>=700 and [MH-Z19#PPM]<=1200
		if %systime% > 08:00:00 and %systime% < 20:00:00 	
			NeoPixelAll,60,60,0,0 // gelb tagsueber
		else 
			NeoPixelAll,8,8,0,0 
		endif
	endif		

	if [MH-Z19#PPM]>=1200
		if %systime% > 08:00:00 and %systime% < 20:00:00 	
			NeoPixelAll,80,0,0,0 // rot tagsueber
		else 
			NeoPixelAll,8,0,0,0 
		endif 
	endif		
endon	

This works:

Code: Select all

On MH-Z19#PPM<700 do
    NeoPixelAll,0,80,0,0  // gruen
endon
	 
On MH-Z19#PPM>700 do
	if [MH-Z19#PPM]<1200
		NeoPixelAll,50,50,0,0 // gelb
	else 
		NeoPixelAll,80,0,0,0 // rot
	endif 
endon	

Can someone help me why the first Rule is not working?

[moebius]

Nested "if" is not allowed:
https://www.letscontrolit.com/wiki/inde ... rial_Rules

[micropet]

OK. I thought that had changed in the meantime.

[grovkillen]

No, not allowed.

[micropet]

Good, thank you both. Then I rebuild the rule.

[micropet]

That seems to work:

Code: Select all

// ----- 
on MH-Z19#PPM do
	if [MH-Z19#PPM]<=700
		event gruen
	endif
	if [MH-Z19#PPM]>=700 and [MH-Z19#PPM]<=1200
		event gelb
	endif
	if [MH-Z19#PPM]>=1200
		event rot
	endif	
endon

on gruen do	
	if %systime% > 08:00:00 and %systime% < 20:00:00 
		NeoPixelAll,0,80,0,0  // gruen tagsueber
	else
		NeoPixelAll,0,8,0,0   // gruen abends
	endif
endon

on gelb do
	if %systime% > 08:00:00 and %systime% < 20:00:00 	
		NeoPixelAll,60,60,0,0 // gelb tagsueber
	else 
		NeoPixelAll,8,8,0,0 
	endif
endon

on rot do
	if %systime% > 08:00:00 and %systime% < 20:00:00 	
		NeoPixelAll,80,0,0,0 // rot tagsueber
	else 
		NeoPixelAll,8,0,0,0 
	endif 
endon	
// ----------